home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d3
/
amac33.arc
/
FILE19.QM
< prev
next >
Wrap
Text File
|
1991-04-28
|
39KB
|
891 lines
* (FILE19).QM
*┌───────────────────────── (INDEX) FileManager Macros ────────────────────────┐
*│
*│@(f) Execute programs requiring filename without full path name <-NEW
*│
*│@(z) LOAD all files in "Ring"
*│@(1) LOAD file from sorted list
*│@(4) LOAD file from "PickList", wild cards OK
*│@(5) LOAD file whose name is at the cursor
*│@(6) re-LOAD current file from disk copy
*│@(3) DELETE file from sorted list
*│@(9) EDIT file from "RingList"
*│@(0) EDIT file from "RingList" if new files have been loaded
*│@(2) READ macfile & LOAD it's txtfile from sorted list
*│@(8) READ macfile of txtfile that is loaded
*│@(f7) READ macfile & LOAD it's txtfile from txtfile list
*│@(f8) READ macfile from macfile list, txtfile is not loaded
*│
*│@(f1) SAVE file with name "Mos_Day_Hour_Min.Ext"
*│@(f2) SAVE file with name "CurrentFileName.Mos_Day"
*│@(f3) SAVE Read-Only files
*│@(f4) EXECUTE Dos command from List
*│@(f5) EXECUTE Dos command from List/ with CurrentFileName
*│@(f6) Turn "DIR" list into a "8.3" list of filenames (T.Farley)
*│
*│@(h) Select Index item with cursor line, then <enter>.
*│@(q)- QUIT all files in "Ring"
*│
*│(Index) - How to locate macro or item below from Index using @h
*│(Description)
*│(Startup)
*│(Macros)
*│(Other) Macros
*│(Version) history
*└────────[ be sure to leave at least one blank line at end of Index ]────────┘
* (Index) Use;
*
* To locate a macro or item in this file, press @h, place the cursor
* line on the desired item in the Index above, and press <enter>.
* See BOOK15.QM for more details.
* (Description):
* (FILE19).QM QEdit macros allow the user to select files from a list
* to: either load a file, read a macfile, delete a file, read a macfile
* of loaded txtfile, save a read-only file, or save files with
* date-time name.
* File sorting is done using DX Directory Extender, v2.11. If the newer
* version 2.60 is used and it is NOT registered, the DX heading will
* show in the file selection window of @1 to @5 and the initial cursor
* line will not be positioned on the first files in the selection list.
* The file selection can be still be made by moving the cursor line to
* the desired file and pressing <enter>. Alternatively, you can either
* register DX or change the macros. I suggest registration. DX is the
* most powerful DOS file and directory manager available.
* For (other) macros, see ALLMACRO.INF
* These macros require "QEdit and QMAC v2.1, February, 1990" or later.
* (Startup): See also FILE.DOC for requirements.
*
* To BEGIN, just type "START FILE" <Enter>. All pertinent files will be
* loaded in the "Ring" for viewing, and FILE19.MAC is read.
* Alternatively, type "START FILE 0" <Enter> and the disk copies of all
* files in the "Ring" will be loaded ready for editing, saving time.
*(Macros):-------------------
*
* ┌────────────────────────────────────────────────────────┐
* │@(z) Load all files in "Ring" │
* └────────────────────────────────────────────────────────┘
*
* This macro is handy if you want to quickly load all files in the
* ring. QEdit has the advantage that the EditFile, just like the QEdit
* command line, can accept multiple file names together, separated by
* spaces. Wild card file specification is also possible. The end result
* is that files can be entered in QEdit's "ring" *without* actually
* loading. Qedit defers loading files in the ring until you either
* EditFile or nextfiles into the file. This macro simply automatically
* "loads" all files in the "Ring" by NextFiling through all files. If
* your hard drive is slow (like mine), you'll appreciate the time
* this macro saves. Run this macro twice to see the difference.
* If a file is set "read-only", press <Esc>, and run the macro until
* all files are loaded. The technique using the NUL file as a place
* marker was written by Kyle Watkins of SemWare and is used here with a
* slight modification.
*
* See also QLSTxx.QM for using this macro to load files from a
* FileList.
*
@z Macrobegin
Editfile '!' Return * Insert -or- GoTo NUL File
Begline Cursorright * Put cursor in Col. 2 of NUL File
LOOP: * Main test loop
Nextfile * Move to next files in Ring
Cursorleft * Move cursor left (need for NUL test)
Jfalse LOOP: * If couldn't move to left, it's not
* the NUL File AND cursor position
* has not changed -- LOOP again
*ELSE
* Check to see if in the NUL File
Cursorleft * Move cursor left for NUL Test
Jfalse END: * If couldn't move left -- We
* ARE in the NUL File and Need
* to END the Macro
*ELSE
Cursorright * Move back to Col. 2 in NUL File
END: * Macro is DONE
Quit * Quit the NUL File
*
* 21 bytes Tue 10-30-1990 20:05:53
*┌──────────────────────────────────────────────────────────────────┐
*│@(1) Selects file to LOAD from sorted list of files in directory │
*└──────────────────────────────────────────────────────────────────┘
*
@1 macrobegin
altwordset * For all file names
editfile "file.srt" return * Load sort list
pause * Select sort type
copy * Copy line to scrap
quit * Quit file.srt
DOS "file-DX " * Make/sort file list
paste return return *
editfile "c:!" return * Load sorted file list
cursordown insertline *
cursordown * Get to first file name line
pause * Pause to select file
begline wordright * Put cursor on file name
markword copy * Mark/copy file name
killfile quit * Kill/quit c:!
editfile paste return * Load file
defaultwordset * Reset default
*
* 68 bytes Sun 09-09-1990 14:38:25
*┌─────────────────────────────────────────────────────────────────────┐
*│@(2) LOAD txtfile/READ macfile from sorted list of files in directory│
*└─────────────────────────────────────────────────────────────────────┘
*
@2 macrobegin
altwordset * For all file names
DOS "file-DX mac d-" * Sort macfiles by date
return return *
editfile "c:!" return * Load sorted file list
cursordown insertline *
cursordown * Get to first file name line
pause * Pause to select
begline * Re-position cursor if moved
find "." return return * Select it and get to dot
cursorright delrtword cursorleft* Delete extension
markword copy * Mark/copy file name - no ext
killfile quit * Kill/quit c:!
editfile paste "qm" return * Load txtfile
defaultwordset * Reset default
macroread paste "mac" return * Read macfile
*
* 78 bytes Sun 09-09-1990 14:38:29
*┌──────────────────────────────────────────────────────────────────┐
*│@(3) Selects file to DELETE from sorted list of files in directory│
*└──────────────────────────────────────────────────────────────────┘
*
* Be careful to select ONLY the file you want deleted.
*
@3 macrobegin
altwordset * For all file names
editfile "file.srt" return * Load sort list
pause * Pause to select sort
markline copy paste * Paste selected line
begline markword * Mark file ext
quit * Quit file.srt
DOS "file-DX " * Make/sort file list
paste return return *
editfile "c:!" return * Load sorted file list
cursordown insertline *
cursordown * Get to first file name line
pause * Pause to select file
begline wordright * Put cursor on file name
markword copy * Select it
insertline * Insert line in c:!
paste * Paste file name
copy * Copy file name to scrap
DOS "del " paste return return * Delete select file
killfile quit * Kill/quit c:!
defaultwordset * Reset default
*
* 84 bytes Sun 09-09-1990 14:38:34
*┌─────────────────────────────┐
*│@(4) Load Files From PickList│
*└─────────────────────────────┘
*
* To run, just press Alt and 4 at the same time. At the prompt "File=",
* enter a [file name(s)] and [file sort option] to make a PickList
* using the following syntax:
*
* [file name(s)] [file sort option] <enter>
*
* where [file sort option] is either "esda".
*
* For example, when entering:
*
* c*.* s- (space must be included between name/sort option!)
*
* a file to load can be selected from a PickList of all files in
* the current directory beginning with the letter "c" sorted by size,
* largest first. Entering file name(s) WITHOUT a sort option, makes
* a PickList sorted by name an then extension.
*
* This macro can sort files in any order. The following information is
* from the file DX.DOC for Directory Extender. Please read this
* document for more information on using the excellent program DX.
*
* Sorting is by name by default. The /SOrt switch without a value sorts
* by name and then extension in ascending order. The sorting
* criteria consists of: "N" for name, "E" for extension, "S" for size,
* "D" for date/time, "A" for attribute. Specifying a letter by itself
* or with a '+' suffix indicates ascending order; specifying a '-'
* suffix indicates descending order.
*
* Examples of the sort options are:
*
* [filename(s)] ne => sort by name and extension
*
* [filename(s)] e-n- => sort files descending by
* extension first and then by
* descending name
*
* [filename(s)] snd- => sort files by ascending size,
* ascending name, and then
* descending date
*
@4 macrobegin
unmarkblock altwordset * For all file names
begline insertline * Insert temp line
"File=" *
endline markcolumn * Start mark
pause * File name?, wild cards OK
markcolumn copy * Mark/copy file name to scrap
delline * Delete temp line
DOS "PICK " paste * Make PickList
return return *
editfile "c:!" return * Load list
cursordown insertline *
cursordown * Get to first file name line
pause * Pause to select file
begline wordright * Put cursor on file name
markword copy * Mark/copy selection to scrap
killfile quit * Kill/quit c:!
editfile paste return * Load file selected
defaultwordset * Reset default
*
* 60 bytes Sun 09-09-1990 14:38:38
* ┌──────────────────────────────────────────────┐
* │@(5) LOADS a file whose name is at the cursor│
* └──────────────────────────────────────────────┘
* This picks up a file name that is sitting at the cursor position in the
* editor, and loads it into another buffer (From SemWare BBS).
*
@5 macrobegin *
altwordset * For all file names
markword * Mark file name
copy * Copy to scrap
editfile * Load it
paste return *
defaultwordset *
*
* 11 bytes Sun 09-09-1990 14:38:43
* ┌───────────────────────────────────────┐
* │@(6) Reloads current file from disk │
* └───────────────────────────────────────┘
*
@6 MacroBegin
SplitLine EditFile CurrentFilename Return NewFile "N" Return
*
* 12 bytes Fri 08-10-1990 15:24:13
*┌─────────────────────────────────────────────┐
*│@(8) Reads macfile of txtfile that is loaded │
*└─────────────────────────────────────────────┘
*
* From MACR27.QM
*
@8 macrobegin
macroread currentfilename backspace backspace "mac" return
*
* 15 bytes Sun 09-09-1990 14:38:55
* ┌────────────────────────────────────────────────────────────────────┐
* │@(9) Make RingList, Load all files in ring, select file to edit │
* └────────────────────────────────────────────────────────────────────┘
*
* Does not make NEW RingList if already made.
* Both @9 and @0 have the disadvantage that each files in the ring is
* loaded and modified while getting each FileName to scratch to make
* the RingList. All files in the ring can be QUIT using @q macro.
*
@9 Macrobegin
prevfile unmarkblock * Move to prevfile so file being
* edited is first files in RingList
editfile "!" return * Load/Edit RingList file !
endline begline * If ! is already made, it has text
jtrue GETFILE: * then GoTo GETFILE
*ELSE
dropanchor *
storescrbuff "1" return * Clear scratch buffer
Begline Cursorright * Put cursor in Col. 2 for StopFile
LOOP: * Main test loop
Nextfile * Move to next files in Ring
splitline dropanchor *
currentfilename *
appendscrbuff "1" return* Append filename to scratch buffer
cut * Delete block
Cursorleft * Move cursor left
* (need for StopFile test)
Jfalse DOIT: * If couldn't move to left, cursor
* must be in Col. 1 and it's not
* the StopFile -- GO with DOIT
*ELSE
* Check to see if in the StopFile File
Cursorleft * Move cursor left for StopFile Test
Jfalse RINGLIST: * If couldn't move left again -- We
* ARE in the StopFile File and Need
* to GO to RINGLIST
*ELSE
Cursorright * Restore Cursor to its previous
* position and GO with the DOIT
DOIT: * DOIT Loop
Jump LOOP: * Return to the Main Loop
RINGLIST: * Get RingList into file
editfile "!" return * Load RingList file
getscrbuff "1" return * Put RingList in it
delline unmarkblock * Delete top line and unmark file
GETFILE: *
pause copy * Pause and select file to edit
editfile paste return * and then begin editing it
*
* 58 bytes Mon 10-01-1990 10:56:15
* ┌────────────────────────────────────────────────────────────────────┐
* │@(0) Make RingList, Load all files in ring, select file to edit │
* └────────────────────────────────────────────────────────────────────┘
*
* Makes NEW RingList even if already made.
* Both @9 and @0 have the disadvantage that each files in the ring is
* loaded and modified while getting each FileName to scratch to make
* the RingList. All files in the ring can be QUIT using @q macro.
*
@0 Macrobegin
prevfile unmarkblock * Move to prevfile so file being
dropanchor * edited is first files in RingList
storescrbuff "1" return * Clear scratch buffer
Begline Cursorright * Put cursor in Col. 2 for StopFile
LOOP: * Main test loop
Nextfile * Move to next files in Ring
splitline dropanchor *
currentfilename *
appendscrbuff "1" return* Append filename to scratch buffer
cut * Delete block
Cursorleft * Move cursor left
* (need for StopFile test)
Jfalse DOIT: * If couldn't move to left, cursor
* must be in Col. 1 and it's not
* the StopFile -- GO with DOIT
*ELSE
* Check to see if in the StopFile File
Cursorleft * Move cursor left for StopFile Test
Jfalse RINGLIST: * If couldn't move left again -- We
* ARE in the StopFile File and Need
* to GO to RINGLIST
*ELSE
Cursorright * Restore Cursor to its previous
* position and GO with the DOIT
DOIT: * DOIT Loop
Jump LOOP: * Return to the Main Loop
RINGLIST: * Get RingList into file
editfile "!" return * Load RingList file
getscrbuff "1" return * Put RingList in it
delline unmarkblock * Delete top line and unmark file
GETFILE: *
pause copy * Pause and select file to edit
Quit * Quit the RingList File
editfile paste return * and then begin editing it
*
* 50 bytes Mon 10-01-1990 11:02:09
* ┌─────────────────────────────────────────────────┐
* │@(f1) Saves file with name "Mos_Day_Hour_Min.Ext"│
* └─────────────────────────────────────────────────┘
*
* This macro saves the current file with the name as
* "Mos_Day_Hour_Min.Ext". For example, @f1 saves this file as
* 08191025.QM when date and time are Sun 08-19-1990 10:25:00.
*
* Insert must be ON.
*
* Thanks to Jim Wright for the neat idea how to condense date and time
* with his macro in QE-MEM.ZIP. Like many other macro ideas from
* others, they often seem so simple once we see and understand them
* that we say "why didn't I think of that" - but I didn't !
@f1 macrobegin
*************************************** TOGGLE INSERT ON*************
insertline * Insert test line
"a" cursorleft "a" * Insert "aa"
endline * If not at endline-insert is on
Jtrue FIN: * If at endline -insert is off
toggleinsert * Toggle ON if off
FIN: *
delline * Delete test line
*************************************** CONDENSE DATE & TIME *******
unmarkblock * Begin no marked block
insertline begline * Insert line
insertdate inserttime * Get date & time to condense
delltword delltword * Delete seconds
backspace * Delete :
cursorleft cursorleft * Keep minutes
backspace * Delete :
cursorleft cursorleft * Keep hour
delltword delltword * Delete spaces and year
backspace * Delete -
cursorleft cursorleft * Keep day
backspace * Delete -
cursorleft cursorleft * Keep month
delltword delltword * Delete spaces & day name
endline * Go to end of condensed number
currentfilename * Get currentfilename
find "." return "b" return * Move to begin of extension
cursorleft markcolumn * Move off dot and mark it
find ":" return "b" return * Move to :
cursorleft deleteblock * Del all but .ext of file name
cut * Get number.ext to scrap
writeblock paste return * Save number.ext
*
* 63 bytes Sat 09-15-1990 09:58:56
* ┌────────────────────────────────────────────────────────┐
* │@(f2) Saves file with name "CurrentFileName.Mos_Day" │
* └────────────────────────────────────────────────────────┘
*
* This macro saves the current file with the name "CurrentFileName.Mos_Day".
* For example, ^@f2 saves it as FILE19.819 when date and time are
* Sun 08-19-1990 10:25:00. Use this macro Jan-Sept.
*
@f2 macrobegin
unmarkblock * Begin no marked block
insertline begline * Insert line
insertdate * Get date & time to condense
delltword delltword * Delete spaces and year
backspace * Delete -
cursorleft cursorleft * Keep day
backspace * Delete -
cursorleft * Keep last digit of month,
backspace * Delete first digit of month
backspace * Delete -
delltword delltword * Delete spaces & day name
begline *
currentfilename * Get currentfilename
delltword * Delete extension
cut * Get file name.num to scrap
writeblock paste return * Save file name.num
*
* 26 bytes Wed 10-03-1990 19:24:02
* * This macro saves the current file with the name "CurrentFileName.Mos_Day".
* * For example, ^@f2 saves it as FILE19.119 when date and time are
* * Sun 10-19-1990 10:25:00. Use this macro Oct-Dec.
* *
* @f2 macrobegin
* unmarkblock * Begin no marked block
* insertline begline * Insert line
* insertdate * Get date & time to condense
* delltword delltword * Delete spaces and year
* backspace * Delete -
* cursorleft cursorleft * Keep day
* backspace * Delete -
* backspace * Delete last digit of month
* cursorleft * Keep first digit of month,
* delltword delltword * Delete spaces & day name
* begline *
* currentfilename * Get currentfilename
* delltword * Delete extension
* cut * Get file name.num to scrap
* writeblock paste return * Save file name.num
* *
* * 25 bytes Fri 10-19-1990 12:53:19
* ┌──────────────────────────────────────────────┐
* │@(F3) Saves Read-Only files │
* └──────────────────────────────────────────────┘
*
* This macro will save the currently loaded file if the file attribute
* on the disk copy is set to Read-Only. QEdit currently will not save
* files loaded as Read-Only.
*
* This macro is written to use either Dos ATTRIB, Gavin's ALTER, or
* Norton's FA. To change from using Dos ATTRIB change the respective
* lines in the macro and reconvert with QMAC.
*
* One word of caution: any file on the disk in the current directory
* with same prefix as the loaded file will have it's read attribute
* reset to read OFF regardless of the extension. Gavin's ALTER is the
* fastest way to reset attributes but it also resets ALL the attributes,
* including the archive bit, of ALL files in the directory with the same
* prefix.
*
* To save a file loaded as Read-Only just press @f3:
@f3 macrobegin
unmarkblock * Unmark blocks
insertline * Insert blank line on top
markcolumn *
currentfilename markcolumn * Get currentfilename on line
storescrbuff "1" return * Store currentfilname to buf/1
find "." return "B" return * Find dot back
jtrue IFEXT: * If dot found go to IFEXT:
endline ".*" * Add ".*" if name has NO ext
jump FULLEXT: * Go to FULLEXT
IFEXT: * If name has extension then..
cursorright deltoeol "*" * Add "*" after dot
FULLEXT: *
copy * Copy "prefix.*" to scrap
delline * Delline
changefilename "$" return * Change currentfilename to $
dos "ATTRIB -R " * Clear Read Only attribute...
paste return return * w/ Dos ATTRIB
* dos "ALTER " *
* paste "/RE" return return * w/ Gavin ALTER (fastest)
* dos "FA " *
* paste "/R-" return return * w/ Norton FA
insertline * Insert blank line in $
unmarkblock * Unmark all blocks
getscrbuff "1" return * Get origfilename on line
copy * Copy to scrap
delline * Delline
changefilename paste return * Change $ to origfilename
return * Gives OK to overlay origfile
savefile * Save origfile
*
* 80 bytes Sat 09-15-1990 09:16:14
* 78 bytes Tue 01-29-1991 19:26:21 changed "B " to "B"
*┌──────────────────────────────────────┐
*│ @(f4) Execute Dos Commands From List │
*└──────────────────────────────────────┘
* To run, just press @f4 and move cursor line to the desired command
* to execute. Then press <enter> to execute command and return to file
* you editing. Modify DOS.LIST as you need.
*
* Run Syntax: [command] <enter>
@f4 Macrobegin
unmarkblock *
editfile "DOS.LST" return * Load command list
pause * Select command
copy * Get command to scrap
quit * Quit command list
DOS paste return return * Execute Dos command
*
* 28 bytes Sat 09-15-1990 08:56:57
*┌──────────────────────────────────────────────────────────┐
*│ @(f5) Execute Dos Commands From List With CurrentFileName│
*└──────────────────────────────────────────────────────────┘
*
* To run, just press @f5 and move cursor line to the desired command
* to execute. Then press <enter> to execute command. Press <enter> again
* to return to file you were editing. Dos executes the command as if it
* were run at the command line followed by the currentfilename, then
* <enter>. Modify the DOS.LIST as you need.
* I recall getting this macro from the SemWare BBS but do not recall
* the author. If anyone knows, please let me know so I can give proper
* credit. It's quite a useful and simple macro.
*
* Run Syntax: [command] CurrentFileName <enter>
*
@f5 Macrobegin
unmarkblock *
editfile "DOS.LST" return * Load command list
pause * Select command
copy * Get command to scrap
quit * Quit command list
DOS paste " " currentfilename * Execute command w/
* currentfilename
return * To return to QEdit
*
* 30 bytes Sat 09-15-1990 09:24:37
* Macro @(f6) does a DIR and ends up with a list of
* filenames in conventional "8.3" format:
*
* *
* * DIRLIST: turn a DOS "DIR" command into a list of filenames.
* *
* * By: Tim Farley (For Ken Housley on RelayNet).
* * Date: October 22, 1990
* *
@f6 MacroBegin
Dos "DIR " Pause EndLine ">$$$.TMP" Return Return
HorizontalWindow EditFile "$$$.TMP" Return
DelLine
DelLine * DELETE THIS LINE IF DOSVER < 4.0
* | This line is needed for Dos 3.3 TH
DelLine DelLine DelLine * Delete header info
DELLINE * | Added FOR DOSVER 3.3, TH
EndFile DelLine * Delete totals line
JFalse abort: * Failed? NO FILES!
BegFile * Back to top line, please.
GotoColumn "13" Return * Just past filename
loopeol:
DelToEol * delete size/date/etc.
CursorDown * go to next file.
JTrue loopeol: * repeat until no more
BegFile * Back to top.
GotoColumn "9" Return * Column where "." goes.
loopdot:
"." CursorLeft * add a "." to each name
CursorDown * try to go to next
JTrue loopdot: * repeat until no more
BegFile
FindReplace " " Return * replace all spaces with
DelLine Return * NOTHING!
"NG" Return * No prompting, just do it.
abort:
KILLFILE * | Added to kill temp file
ESCAPE ESCAPE * | Added to eliminate
* |"changes made" message, TH
*
* 96 bytes Mon 10-22-1990 22:25:14 (added TH)
* 100 bytes Sun 10-28-1990 11:58:10 (added TH)
* The above macro would require QEdit 2.1 and QMAC 2.1 for use. If
* you want to put it in your QCONFIG.DAT, remove all the comments
* and reformat it so it fits all on one line.
*
* Thanks for the detailed comments about WordRight/WordLeft.
*
* --Tim Farley
* SemWare Technical Support
* ┌─────────────────────────────────────────────────────────┐
* │@(f7) READ macfile & LOAD it's txtfile from txtfile list │
* └─────────────────────────────────────────────────────────┘
*
* @f7 enables a file to be selected for editing and it's macfile read
* from a prepared list of txtfiles. The list of txtfiles (-qm.lst)
* included with FILE19 is a list of the latest macros in this series,
* but it can be altered to meet your needs by adding [drive:]\[path\]
* both in front of each files in the list and also in the second line of
* the macro, and adding or deleting any files you choose to/from this
* list. The modified macro can be put in your QCONFIG.DAT file and
* macros can be loaded and read while in any directory. To run, press
* @f7, cursor down to the desired file, and press <enter>. Remember,
* txtfiles must have the extension "QM" and the macfiles must have the
* extension "MAC".
*
@f7 macrobegin
editfile "-qm.lst" return * Edit txtfile list
pause * Pause to select macro to read
endline * Go to end of file name
backspace backspace * and remove it's extension
copy quit * Copy file name to scrap
editfile paste "qm" return * Load selected macro txtfile
macroread paste "mac" return * and read it's macfile
*
* 42 bytes Thu 10-18-1990 12:23:41
*┌───────────────────────────────────────────────────────────┐
*│ @(f8) READ macfile from macfile list, txtfile not loaded │
*└───────────────────────────────────────────────────────────┘
*
* @f8 enables a macfile to be selected and read from a prepared list
* of macfiles. The list of macfiles (-mac.lst) included with FILE19 is
* a list of the latest macros in this series, but it can be altered to
* meet your needs by adding [drive:]\[path\] in front of each files in
* the list and also in the second line of the macro, and adding or
* deleting any files you choose to/from this list. The modified macro
* can be put in your QCONFIG.DAT file and macros can be read while in
* any directory. To run, press @f8, cursor down to the desired file,
* and press <enter>. Remember, macfiles must have the extension "MAC".
*
@f8 macrobegin
editfile "-mac.lst" return * Edit macfile list
pause * Pause to select macro to read
endline * Go to end of macfile name
backspace backspace backspace * and remove it's extension
copy quit * Copy macro name to scrap
macroread paste "mac" return * Read it's macfile only
*
* 38 bytes Thu 10-18-1990 12:23:50
*┌───────────────────────────────────────────────────────────────────┐
*│@(h) Finds first word on cursor line marked in document below │
*└───────────────────────────────────────────────────────────────────┘
*
* @h macro has 2 steps:
*
* 1. Press @ and h at the same time. An ! shows at the
* end of the top line. Cursor down to desired line in Index.
*
* 2. Press Enter. The macro first erases the !, and
* then finds the first word on the cursor line in the document
* below marked with (...).
*
* See BOOK15.QM for more details.
*
@h macrobegin
unmarkblock * Unmark any marked blocks
begfile endline * Go to file begin endline
"!" * Put ! at endline
begline
find "!" return return begline * Highlight !
pause * Pause for Index selection
wordright markword * Mark first word on line
copy * Copy word to scrap buffer
begfile * Begfile
find "!" return return delch * Find & delete !
endpara * Go to end of Index
makectrofscreen * Cursor line center of window
find "(" paste ")"
return "I" return * Find first marked word in doc
jfalse NOMARK:
begline * If mark found go to begline
jump END:
NOMARK:
begfile * If no mark found go to begfile
END:
*
* 47 bytes Fri 09-14-1990 14:06:26
*┌──────────────────────────────────┐
*│@(q) QUITs all Files in Ring │
*└──────────────────────────────────┘
*
@q macrobegin
LOOP:
quit
jump LOOP:
*
* 8 bytes Sat 09-29-1990 00:03:46
*┌────────────────────────────────────────────────────────────────┐
*│@(f) Executes programs requiring filename without full pathname │
*└────────────────────────────────────────────────────────────────┘
*
@f MacroBegin
Unmarkblock Insertline * Insert temp line
Currentfilename * with currentfilename
MarkCharacter * Begin mark
Find "\" Return "B" Return * Find \ backwards
CursorRight Cut * Cut filename to scrap
Delline * Delete temp line
Dos "dir " Paste Return * Execute "dir"
** Change "dir " to "program " name
*
* 29 bytes Wed 01-23-1991 20:59:24
* (Version) History:
*
* 1.0 - Initial version named SORT10.ZIP
* 1.1 - changed and shortened Alt-f3 to keep extraneous files
* from ring
* - Changed file names from SORTxx.xxx to FILExx.xxx.
* 1.2 - DX Directory Extended not included to save download time.
* 1.2a- Changed other file names in series, this is an update.
* 1.3 - Added @4 to load files from PickList, wild cards OK.
* - Changed j:$ to c:! in macros and batch file.
* - Changed .QL and .LST files.
* - Changed key assignments from alternate_functions
* to alternate_numbers.
* - All macros shortened.
* 1.4 - FILE-DX.BAT was not sa:ving "echo .." initialization; corrected.
* - Modified macros @1-4 so Insert does NOT have to be ON.
* - Added AltWordSet to @1-4 to get all files.
* - Removed need to use scratch buffers in @3.
* - Added @5 to LOAD a file whose name is at the cursor.
* - Added @6 to execute Dos Commands From List.
* - Added @7 to EXECUTE DOS commands from List
* with CurrentFileName.
* - Added @8 to read macfile of txtfile that is loaded.
* - Added ^3 to save Read-Only files.
* - Added ^1 and ^2 to save files with date-time name.
* - Modified @1-4 and batch files to exclude directories in file
* list and PickList.
* - Removed check to quit c:! if already loaded in @1-4.
* - Changed @4 to use only PICK.BAT.
* 1.5 - Added @9 to select file to edit from RingList
* - Added @0 to select file to edit from RingList if new files have
* been loaded since making last RingList
* - Added @h to FIND items or macros in Index.
* - Added @q to QUIT all files in ring.
* 1.6 - Added @6 to re-LOAD current file from disk copy.
* - Modified @9 and @0 to be faster and shorter.
* - Modified @f2 for correct extension Oct-Dec.
* - Changed @f1 thru @f5 key assignments.
* 1.7 - Added @f6 to turn "DIR" command into a "8.3" list of filenames,
* written by T. Farley of SemWare.
* - Added @f7 and @f8 to read and load txtfiles and macfiles from
* a prepared list of active txtfiles and macfiles.
* - Modified @f2 for Oct-Dec and added alternate version
* for Jan-Sept.
* - DOS.LST was inadvertantly left out of versions since 1.4.
* It is now included.
* 1.8 - Modified @f6 for DOS Ver 3.3, other Dos versions not tested.
* - Modified documentation and added START.BAT.
* - Added @z to load all files in "Ring" buffer.
* - Modified @f2 for Jan-Sep and added alternate version
* for Oct-Dec.
* 1.9 - Added @f to execute programs requiring filename without full path name.
* - Corrected @h Index Use instructions.
* - Shortened @f3 2 bytes.
* Tom Hogshead Tue 01-29-1991
